home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Publication 11
/
Publication_11_19xx_-_de_Side_B.d64
/
t_s-info imprvd.
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2023-02-26
|
2KB
|
76 lines
1 rem *********************************
2 rem * vitals 1541 *
3 rem *********************************
4 rem * will corley *
5 rem * 7551 twilight dr. *
6 rem * sacramento, ca *
7 rem * 95822 *
8 rem *********************************
9 dc$="":for x=1 to 44:read a:dc$=dc$+chr$(a):next
10 poke 53280,11:poke 53281,12:print "[147]"
11 i=512:k$=chr$(0)
12 print tab(14) "vitals 1541"
13 print tab(14) "[151][183][183][183][183][183][183][183][183][183][183][183]"
14 print tab(10)"(c) by will corley"
15 input "[151]file to analyze";n$
16 if len(n$)>16 or n$="" then run
17 close 15:open 15,8,15,"i":gosub 49:ty$="p":a=1
18 open 2,8,2,n$+","+ty$+",r"
19 input#15,e:if e<20 then 26
20 close 2
21 if e<>64 then run
22 if a=1 then ty$="s"
23 if a=2 then ty$="u"
24 if a=3 then run
25 a=a+1:goto 18
26 get#2,a$:sl=peek(512):get#2,a$:sh=peek(512)
27 print#15,"m-r" chr$(24) k$ chr$(2)
28 get#15,a$:t=peek(i):get#15,a$:s=peek(i)
29 close 2:print#15,"u;":open 2,8,2,"#3":gosub 49:print#15,"b-p";2;0
30 print#2,dc$;
31 print#15,"m-w" chr$(6) chr$(0) chr$(2) chr$(t) chr$(s)
32 print#15,"m-e" chr$(0) chr$(6):close 2
33 print#15,"m-r" chr$(10) k$ chr$(2)
34 get#15,a$:l=peek(i):get#15,a$:h=peek(i)
35 print#15,"m-r" chr$(1) chr$(3) chr$(1)
36 get#15,a$:bytes=peek(i)-1
37 close 15
38 print "[151]file type: ";
39 if ty$="p" then print "program"
40 if ty$="s" then print "sequential"
41 if ty$="u" then print "user"
42 print "[151]blocks:" h*256+l
43 print "[151]bytes:" (h*256+l-1)*254+bytes-1
44 if ty$<>"p" then 46
45 print "[151]start address:"sh*256+sl
46 print "[151]starting track:"t
47 print "[151]starting sector:"s:gosub100
48 poke 198,0:wait 198,1:goto 54
49 input#15,e,e$,et,es:if e<20 then return
50 close 2:close 15
51 print "disk error"
52 print e,e$,et;es
53 ti$="000000":wait 161,1:run
54 print "[147]"
55 print" vitals 1541 has been released to the public domain as freeware";
56 print".a donation of $1,5 or 10 would gladly be accepted!"
57 print " support the freeware concept!"
58 print tab(14)"will corley"
59 print tab(11)"7551 twilight dr."
60 print tab(13)"sacramento,ca"
61 print tab(17)"95822"
62 ti$="000000":wait 161,1:run
63 dc$="":y=49152:for x=1 to 184:read a:dc$=dc$+chr$(a):next:return
64 data 169,0,133,10,133,11,169,176,133,0
65 data 165,0,48,252,169,128,133,0,165,0
66 data 48,252,230,10,208,2,230,11,173,0
67 data 3,208,1,96,133,6,173,1,3,133
68 data 7,24,144,218
100 rem *******************************
101 rem * improved by zeitgeist for *
102 rem * da ql mag publication *
103 rem *******************************
104 d=sh*256+sl
105 z$="":b=16:forg=0to0:d=d/b:h=(d-int(d))*b:z$=chr$(55+h+7*(h<10))+z$
106 g=-d:next:print"[151]hex-anfang : $"z$:return